home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
The Glitch Apple Disk Collection
/
2014.glitch.apple.collection.zip
/
indexed
/
33MASTER.DSK
/
COLOR DEMOSOFT.bas
< prev
next >
Wrap
BASIC Source File
|
2014-09-09
|
3KB
|
68 lines
30 U = 9:D = 3:E = -16384:F = -16368:G = -16287:H = -16286:Z = 127
100 POKE 768,173: POKE 769,48: POKE 770,192: POKE 771,136: POKE 772,208: POKE 773,4: POKE 774,198: POKE 775,7
110 POKE 776,240: POKE 777,8: POKE 778,202: POKE 779,208: POKE 780,246: POKE 781,166: POKE 782,6: POKE 783,76: POKE 784,0: POKE 785,03: POKE 786,96
200 TEXT : HOME : PRINT : POKE F,0
220 A$ = "APPLE DEMONSTRATION PROGRAMS": GOSUB 2000: PRINT
230 PRINT " TO OPERATE A DEMONSTRATION, TYPE"
240 PRINT "ITS NUMBER. THEN TYPE THE KEY MARKED"
250 PRINT "'RETURN' AT THE RIGHT EDGE OF THE KEY-"
260 PRINT "BOARD. TYPE THE 'RETURN' KEY TO STOP"
270 PRINT "ANY DEMONSTRATION.": PRINT : PRINT
290 PRINT "1.";
300 A$ = "STANDARD COLOR NAMES": GOSUB 2000
310 PRINT "2.";
320 A$ = "STANDARD COLOR NUMBERS": GOSUB 2000
330 PRINT "3.";
340 A$ = "KALEIDOSCOPE": GOSUB 2000
350 PRINT "4.";
360 A$ = "SKETCHING SCREEN": GOSUB 2000
370 PRINT : PRINT
380 INPUT "WHICH WOULD YOU LIKE?";A$
390 IF LEN(A$) = 0 THEN GOTO 200
395 N = ASC(A$) -48
400 IF N <1 OR N >4 THEN GOTO 200
410 ON N GOTO 500,600,700,800
450 IF PEEK(E) <Z THEN 450
460 GOTO 200
500 GOSUB 3000
510 A$ = "BMDPDGMLBOGPLYAW": GOSUB 4000: PRINT
520 A$ = "LGBUGRBBRRRIGEQI": GOSUB 4000: PRINT
530 A$ = "ATLRRELLWNENRLUT": GOSUB 4000: PRINT
540 A$ = "KAUPNYUUNGYKNOAE": GOSUB 4000
550 GOTO 450
600 GOSUB 3000
610 FOR I = 0 TO 14 STEP 2
620 HTAB 2 *I +4: PRINT I;
630 NEXT I: PRINT
640 FOR I = 1 TO 15 STEP 2
650 HTAB 2 *I +4: PRINT I;
660 NEXT I: PRINT : PRINT : GOTO 450
700 GR : HOME : FOR W = 3 TO 50: FOR I = 1 TO 19: FOR J = 0 TO 19:K = I +J: IF PEEK(E) >Z THEN 200
750 COLOR= J *3/(I +3) +I *W/12
760 PLOT I,K: PLOT K,I: PLOT 40 -I,40 -K: PLOT 40 -K,40 -I
770 PLOT K,40 -I: PLOT 40 -I,K: PLOT I,40 -K: PLOT 40 -K,I
780 NEXT J,I,W: GOTO 450
800 HOME :A$ = "USE THE GAME CONTROLS AND BUTTONS.": GOSUB 2000
810 A$ = "THE BUTTONS CLEAR THE TV AND CHANGE": GOSUB 2000
820 A$ = "THE DISPLAYED COLOR. TRY ONE NOW.": GOSUB 2000
900 IF PEEK(G) >Z OR PEEK(H) >Z THEN 930
910 IF PEEK(E) >Z THEN 200
920 GOTO 900
930 HOME : GR
940 P = PDL(0):X = INT(P/6): IF X >39 THEN X = 39
950 I = PDL(1):Y = INT(I/6): IF Y >39 THEN Y = 39
960 P = INT((I +P)/2 +9): IF P >255 THEN P = 255
970 GOSUB 1500
980 VTAB 21: PRINT "X IS ";X;" ": PRINT "Y IS ";Y;" "
990 IF PEEK(E) >Z THEN 200
1000 IF PEEK(G) >Z THEN GR
1010 IF PEEK(H) >Z THEN U = (U +1)
1015 IF U = 16 THEN U = 0
1020 COLOR= U: PLOT X,Y: GOTO 940
1500 POKE 6,P: POKE 7,D: CALL 768: RETURN
2000 HTAB ((40 - LEN(A$))/2 +1): PRINT A$: PRINT : RETURN
3000 GR : FOR I = 0 TO 31: COLOR= I/2: VLIN 0,39 AT I +3: NEXT I
3010 COLOR= 5: VLIN 0,39 AT 2: VLIN 0,39 AT 35: HLIN 2,35 AT 0: HLIN 2,35 AT 39: RETURN
4000 FOR I = 1 TO LEN(A$)
4010 HTAB 2 *I +2: PRINT MID$ (A$,I,1);
4020 NEXT I: RETURN